DAY()
 Return the day of the month as a numeric value
------------------------------------------------------------------------------
 Syntax

     DAY(<dDate>) --> nDay

 Arguments

     <dDate> is a date value to convert.

 Returns

     DAY() returns a number in the range of zero to 31 as an integer numeric
     value.  If the month is February, leap years are considered.  If the
     date argument is February 29 and the year is not a leap year, DAY()
     returns zero.  If the date argument is empty, DAY() returns zero.

 Description

     DAY() is a date conversion function used to convert a date value to the
     day of a month.  This function is used in combination with CMONTH() and
     YEAR() to format dates.  In addition, it is often used in various date
     calculations.

 Examples

     .  These examples show the DAY() function used several ways:

        ? DATE()                             // Result: 09/01/90
        ? DAY(DATE())                        // Result: 1
        ? DAY(DATE()) + 1                    // Result: 2
        ? DAY(CTOD("12/01/94"))              // Result: 1

     .  This example uses DAY() in combination with CMONTH() and
        YEAR() to format a date value:

        ? CMONTH(DATE()) + STR(DAY(DATE())) +;
           "," + STR(YEAR(DATE()))      // Result: June 15, 1990

 Files   Library is CLIPPER.LIB.

See Also: CDOW() CMONTH() DOW() MONTH() STR() YEAR()