Page 1 of 1
Agregar un control en tiempo de ejecucion.
Posted: Wed Oct 15, 2014 10:41 pm
by mjaviergutierrez
Hola: como agrego un control en tiempo de ejecución.
Tengo un form generado con el IDE y como no puedo cambiar la propiedad InputMask del TEXTBOX, en tiempo de ejecución, la destruyo y quiero agregar un nuevo TEXTBOX con la nueva InputMask.
Lo pruebo con @ 99,99 TEXTBOX y con DEFINE TEXTBOX pero el IDE me da error al compilar.
No encuentro nada en el foro, si alguien puede ayudarme desde ya muchas gracias.
Gracias. Saludos.
Re: Agregar un control en tiempo de ejecucion.
Posted: Wed Oct 15, 2014 11:37 pm
by danielmaximiliano
Fijate
Code: Select all
/*
@ 46 , 70 TEXTBOX &cText PARENT Principal ;
VALUE cText ;
MAXLENGTH 10
*/
cNote := 'example of using AddPage method, AddControl and pseudo Backcolor in controls Tab '
cText := "Text_" + ltrim(str(nPage))
Win_1.Tab_1.AddControl(cText , nPage, 46 , 70 )
Re: Agregar un control en tiempo de ejecucion.
Posted: Wed Oct 15, 2014 11:37 pm
by Javier Tovar
Hola Javier, espero te sirva!
Code: Select all
#include "hmg.ch"
Function Main
SET NAVIGATION EXTENDED
DEFINE WINDOW Form_1 ;
AT 0,0 ;
WIDTH 400 ;
HEIGHT 500 ;
TITLE 'InputMask Demo' ;
MAIN
DEFINE MAIN MENU
POPUP 'Test'
ITEM 'Borra Control y Aparece otro, MAGIA?, NO solo aprender un poco más!' ACTION CreaControl()
END POPUP
END MENU
@ 10,10 TEXTBOX Text_1 ;
VALUE 1234567.12 ;
NUMERIC INPUTMASK "$9,999,999.99"
@ 50,10 TEXTBOX Text_2 ;
VALUE 1234.56 ;
NUMERIC INPUTMASK "$9,999.99" FORMAT 'CX'
@ 90,10 TEXTBOX Text_3 ;
VALUE -123.0 ;
NUMERIC INPUTMASK "999,999.99" FORMAT '('
@ 130,10 TEXTBOX Text_4 ;
VALUE 123.0 ;
NUMERIC INPUTMASK "999.9"
@ 170,10 TEXTBOX Text_5 ;
VALUE -123.45 ;
NUMERIC INPUTMASK "$9,999.99" FORMAT 'CX'
@ 210,10 TEXTBOX Text_6 ;
VALUE 1234.56 ;
NUMERIC INPUTMASK "$***,999.99"
@ 250,10 TEXTBOX Text_7 ;
VALUE 12345678.12 ;
NUMERIC INPUTMASK "99999999.99"
@ 290,10 TEXTBOX Text_8 ;
VALUE 1.1 ;
NUMERIC INPUTMASK "9.9"
@ 330,10 TEXTBOX Text_9 ;
VALUE 1234567890.12 ;
NUMERIC INPUTMASK "$9999999999.99"
@ 370,10 TEXTBOX Text_10 ;
VALUE 123456 ;
NUMERIC INPUTMASK "$9999999"
@ 410,10 TEXTBOX Text_11 ;
VALUE 1234.56 ;
NUMERIC INPUTMASK "99,999.99" FORMAT 'E'
END WINDOW
CENTER WINDOW Form_1
ACTIVATE WINDOW Form_1
Return
*----------------------------------------------------------------
PROCEDURE CreaControl()
Form_1.Text_1.Release
@ 10,10 TEXTBOX Text_1 ;
PARENT Form_1 ;
VALUE 12345 ;
NUMERIC INPUTMASK "999999999"
RETURN NIL
Saludos
Re: Agregar un control en tiempo de ejecucion.
Posted: Thu Oct 16, 2014 12:23 am
by mjaviergutierrez
Muchas Gracias. Eso era.
Saludos.