HMG 3.0.0 + IDE + HFCL (Forum Test VIII)

[Roberto Lopez]

I found a bug in IDE 3 test 8
It doesn't recompile changed forms! Only changing prg files causes recompilation of project!!!

Is working fine here!!!!!

I've tested with 'multiwin' sample. Changing any thing in any of the forms, recompiles and updates ok.

Please, check your installation and if the problem persist, please, send me a complete sample project.

Regards,

Roberto.

[Roberto Lopez]

I found a bug in IDE 3 test 8
It doesn't recompile changed forms! Only changing prg files causes recompilation of project!!!

Is working fine here!!!!!

I've tested with 'multiwin'

Roberto.

And... if someone can test too, we could confirm that the problem exists and in wich circumstances it arises.

Regards,

Roberto.

[Mario Mansilla]

Hola Roberto :
Instalo la nueva version (Test 8) y compruebo que no realiza el build cuando modifico alguna propiedad del form .
Te envio un ejemplo simple .
Saludos
Mario Mansilla

Hola Roberto:
Install the new version (Test 8) and see that does not perform the build when I change some property of the form.
I sent a simple example.

Greetings
Mario Mansilla

[esgici]

Hi All

The IDE build a temp DIR under working DIR named .hbmk with read-only and hidden properties.

Under some circumstance this DIR can't removed after compilation and remain intact. Because it's hidden, we can't see it under normal conditions. And when we attempt rebuild the project, since this DIR and its content is exist, some modules, especially forms remain non-compiled.

Our Maestro will resolve this problem certainly. Until that, we could continue working by removing this temp DIR.

If you can't see it please use DOS command such as DIR /AD or simply change "hidden files and folders" option in "view" tab of "Folder Options" of "Tools" of Windows Explorer.

Regards

--

Esgici

[Roberto Lopez]

Hi All

The IDE build a temp DIR under working DIR named .hbmk with read-only and hidden properties.

Under some circumstance this DIR can't removed after compilation and remain intact. Because it's hidden, we can't see it under normal conditions. And when we attempt rebuild the project, since this DIR and its content is exist, some modules, especially forms remain non-compiled.

Our Maestro will resolve this problem certainly. Until that, we could continue working by removing this temp DIR.

If you can't see it please use DOS command such as DIR /AD or simply change "hidden files and folders" option in "view" tab of "Folder Options" of "Tools" of Windows Explorer.

Regards

--

Esgici

It is quite strange. It works for me with the samples at \hmg\ide\samples.

IDE just calls BUILD.BAT now with adequate parameters, so, the problem (if exists) is in build.bat.

I'll do some tests. Any ideas are welcome.

Regards,

Roberto.

[mol]

I think, problem exists in buld.bat.

Do you remember first release of hmg 3.0 - that was the same - update forms under IDE doesn't cause recompiling all project

[Roberto Lopez]

Hola Roberto :
Instalo la nueva version (Test 8) y compruebo que no realiza el build cuando modifico alguna propiedad del form .
Te envio un ejemplo simple .
Saludos
Mario Mansilla

Hola Roberto:
Install the new version (Test 8) and see that does not perform the build when I change some property of the form.
I sent a simple example.

Greetings
Mario Mansilla

Ii've verified.

I'll work on it.

Regards,

Roberto.

[Roberto Lopez]

Ii've verified.

I'll work on it.

Regards,

Roberto.

Maybe you (MOL, Esgici) could help in this.

I've tested many many times, \hmg\ide\samples\multiwin sample in test VIII.

Anytime that I change something in a form, the calling programs are recompiled ok.

When I try the sample posted by Mario Mansilla, the project is not recompiled when form was changed.

What is the difference?

I can't find the reason...

Regards,

Roberto.

[Roberto Lopez]

Ii've verified.

I'll work on it.

Regards,

Roberto.

Maybe you (MOL, Esgici) could help in this.

I've tested many many times, \hmg\ide\samples\multiwin sample in test VIII.

Anytime that I change something in a form, the calling programs are recompiled ok.

When I try the sample posted by Mario Mansilla, the project is not recompiled when form was changed.

What is the difference?

I can't find the reason...

Regards,

Roberto.

In fact, if you go to \hmg\ide\samples\multiwin and create (if not exist already) multiwin.hbp file containing project prg names and do:

build /i multiwin.hbp

App, will be created.

If you modify main.fmg file and call the command again:

build /i multiwin.hbp

main.prg only will be recompiled and the project updated.

Why Mario's project do not work?

I'll still experimenting, but any ideas are truly welcome...

TIA.

Regards,

Roberto.

[Roberto Lopez]

I can't find the reason...

I've modified build.bat to create and show the 'build.log' file showing the build details when there is no error.

It could help us to determine what's happening.

Code: Select all

@echo off

cls

rem ***************************************************************************
rem HMG 3.0 Build batch 
rem Roberto Lopez (2009.10.22)
rem ***************************************************************************

rem ***************************************************************************
rem Set variables
rem ***************************************************************************

Set HmgPath=%~dp0

Set Path=%HmgPath%\util;%HmgPath%\mingw\bin;%HmgPath%\harbour\bin;

Set Resources=%HmgPath%\resources\minigui.o

set GT=-gtgui
set DEBUG=""
set BUILDTYPE=""
set REBUILDALL=""
set RUN=.T.
set MT=

rem ***************************************************************************
rem
rem Syntax:
rem
rem	Build [/i|/r|/d|/cs|/ci/cr] <PrgFile> | <filelist.hbp> [config.hbc]
rem	
rem	[/i] : incremental build
rem	[/r] : incremental build (rebuild all)
rem
rem	[/cs] : Console/mixed mode (std build)
rem	[/ci] : Console/mixed mode (incremental build)
rem	[/cr] : Console/mixed mode (incremental rebuild all)
rem
rem	[/d] : Debug mode (gui and console)
rem	
rem
rem	<filelist.hbm> : A text file with .hbp extension containing a source list
rem	<configfile.hbc>: A text file with configuration parameters as additional
rem	libs, include paths and lib paths.
rem 
rem		<configfile.hbc> Syntax:
rem 
rem		incpaths = incpath1 incpath2 ... incpathn
rem                   
rem		libpaths = libpath1 libpath2 ... libpathn
rem 
rem		libs = lib1 lib2 ... libn
rem
rem	- library names must not include 'lib' prefix nor '.a' extension.
rem
rem	- build.bat will create an 'error.log' file in the app folder when build
rem	process ends with an error condition.
rem
rem
rem ***************************************************************************

cls

echo building...

if exist hbmk.log del hbmk.log
if exist windres.log del windres.log
if exist error.log del error.log
if exist _hmg_resconfig.h del _hmg_resconfig.h

rem ---------------------------------------------------------------------------
rem Parameters Processing
rem ---------------------------------------------------------------------------

rem ***************************************************************************
rem NO PARAMETERS OR HELP REQUESTED
rem ***************************************************************************

if "%1"=="" goto syntax
if "%1"=="/?" goto syntax
if "%1"=="-?" goto syntax
if "%1"=="/h" goto syntax
if "%1"=="/H" goto syntax
if "%1"=="-h" goto syntax
if "%1"=="-H" goto syntax
if "%1"=="-help" goto syntax
if "%1"=="-HELP" goto syntax

rem ***************************************************************************
rem No run after build
rem ***************************************************************************

if "%1"=="/n" goto norun
if "%1"=="/N" goto norun

:continue0

rem ***************************************************************************
rem Multi Thread
rem ***************************************************************************

if "%1"=="/mt" goto multithread
if "%1"=="/MT" goto multithread

:continue1

rem ***************************************************************************
rem Console Incremental Rebuild
rem ***************************************************************************

if "%1"=="/cr" goto consoleincrebuild
if "%1"=="/CR" goto consoleincrebuild

rem ***************************************************************************
rem Console Incremental
rem ***************************************************************************

if "%1"=="/ci" goto consoleincremental
if "%1"=="/CI" goto consoleincremental

rem ***************************************************************************
rem GUI Incremental Rebuild
rem ***************************************************************************

if "%1"=="/r" goto increbuild
if "%1"=="/R" goto increbuild

rem ***************************************************************************
rem Console Standard Build
rem ***************************************************************************

if "%1"=="/cs" goto console
if "%1"=="/CS" goto console

rem ***************************************************************************
rem If debug mode specified, use GTWIN and pass -b parameter
rem ***************************************************************************

if "%1"=="/d" goto debug
if "%1"=="/D" goto debug

rem ***************************************************************************
rem If /i parameter rceived set BUILDTYPE to incremental
rem ***************************************************************************

if "%1"=="/i" goto incremental
if "%1"=="/I" goto incremental

rem ***************************************************************************
rem If /i parameter rceived set BUILDTYPE to incremental
rem ***************************************************************************

if "%1"=="/i" goto incremental
if "%1"=="/I" goto incremental

:continue

if exist %~n1.exe del %~n1.exe

if exist %~n1.exe goto error

rem ***************************************************************************
rem If a resource with the same base name as the first parameter exist compile it
rem ***************************************************************************

if exist %~n1.rc  echo #define HMGRPATH %HmgPath%\RESOURCES > _hmg_resconfig.h

if exist %~n1.rc copy /b %HmgPath%\resources\minigui.rc+%~n1.rc+%HmgPath%\resources\filler _temp.rc >NUL
if exist %~n1.rc redir -e windres.log windres -i _temp.rc -o _temp.o 
if exist %~n1.rc Set Resources=_temp.o

rem ***************************************************************************
rem invoke HBMK2
rem ***************************************************************************

redir -eo  hbmk2 -o%~n1.exe %GT% %DEBUG% %MT% %BUILDTYPE% %REBUILDALL% -incpath=%HmgPath%\include -incpath=%CD% -L%HmgPath%\lib -lminigui -lhbmysql -lmysql -lcrypt -ledit -leditex -lgraph -lini -lreport -lhbwin -lhbziparc -lhbmzip -lmsvfw32 -lvfw32 -lsddodbc -lrddsql -lsddmy -lhbodbc -lodbc32 -lhbhpdf -lhbvpdf -lhbmemio -lhbsqlit3 -lsqlite3 -lhbfimage.a -lhbpgsql -lpq -lhbtip -lhbct -lhbmisc -lhbnetio -prgflag=/q %1 %2 %3 %4 %5 %6 %7 %8 %9 %Resources%  >hbmk.log

goto end

rem ***************************************************************************
rem Procedure increbuild
rem ***************************************************************************

:increbuild

set BUILDTYPE=-inc
set REBUILDALL=-rebuild

shift

goto continue

rem ***************************************************************************
rem Procedure Console
rem ***************************************************************************

:console

set GT=-gtwin

shift

goto continue

rem ***************************************************************************
rem Procedure Debug
rem ***************************************************************************

:debug

set GT=-gtwin
set DEBUG=-b

echo Options NoRunAtStartup > Init.cld

shift

goto continue

rem ***************************************************************************
rem Procedure Incremental
rem ***************************************************************************

:Incremental

set BUILDTYPE=-inc -head=real


shift
goto continue

rem ***************************************************************************
rem Procedure IncConsole
rem ***************************************************************************

:consoleincremental

set BUILDTYPE=-inc
set GT=-gtwin

shift

goto continue

rem ***************************************************************************
rem Procedure IncConsole
rem ***************************************************************************

:consoleincrebuild

set BUILDTYPE=-inc
set GT=-gtwin
set REBUILDALL=-rebuild

shift

goto continue

rem ***************************************************************************
rem Procedure NoRun
rem ***************************************************************************

:norun

set RUN=.F.

shift

goto continue0

rem ***************************************************************************
rem Procedure Multithread
rem ***************************************************************************

:multithread

set MT=-mt

shift

goto continue1

rem ***************************************************************************
rem Procedure Error
rem ***************************************************************************

:error

echo Can't delete previous %~n1.exe version (still running?) > error.log

goto showlog

rem ***************************************************************************
rem Procedure Syntax
rem ***************************************************************************

:syntax

cls
echo :: Syntax:
echo ::
echo :: "Build [/i|/r|/d|/cs|/ci/cr] <PrgFile> | <filelist.hbp> [config.hbc]"
echo ::
echo :: [/i] : incremental build
echo :: [/r] : incremental build (rebuild all)
echo :: [/cs] : Console/mixed mode (std build)
echo :: [/ci] : Console/mixed mode (incremental build)
echo :: [/cr] : Console/mixed mode (incremental rebuild all)
echo :: [/d] : Debug mode (gui and console)
echo :: filelist.hbm : A text file with .hbp extension containing a source list
echo :: configfile.hbc: A text file with configuration parameters as additional
echo :: libs, include paths and lib paths.
echo ::
echo :: configfile.hbc Syntax:
echo ::
echo :: incpaths = incpath1 incpath2 ... incpathn
echo :: libpaths = libpath1 libpath2 ... libpathn
echo :: libs = lib1 lib2 ... libn
echo ::
echo :: library names must not include 'lib' prefix nor '.a' extension.
echo :: build.bat will create an 'error.log' file in the app folder when build
echo :: process ends with an error condition.
echo ::
pause
goto stop

:end

rem ***************************************************************************
rem Cleanup
rem ***************************************************************************

rem If build error, create 'error.log' ----------------------------------------

if errorlevel 1 if exist windres.log copy /b windres.log+hbmk.log error.log >nul
if errorlevel 1 if not exist windres.log copy /b hbmk.log error.log >nul

rem If no build error, create 'build.log' ----------------------------------------

if errorlevel 0 if exist windres.log copy /b windres.log+hbmk.log build.log >nul
if errorlevel 0 if not exist windres.log copy /b hbmk.log build.log >nul


rem If no error run the exe ---------------------------------------------------

if "%RUN%"==".T." if not errorlevel 1 if exist %~n1.exe %~n1.exe

rem Delete temporary files ----------------------------------------------------

if exist windres.log del windres.log
if exist hbmk.log del hbmk.log
if exist _hmg_resconfig.h del _hmg_resconfig.h

if exist _temp.rc del _temp.rc

if exist _temp.o  del _temp.o

:showlog

if exist error.log type error.log
if exist build.log type build.log

:stop

Regards,

Roberto.